************************************************
**És l’independentisme més d’esquerres?*********
************************************************

*Jordi Muñoz 
**jordi.munoz@ub.edu
*3/9/2018

*Dades: http://upceo.ceo.gencat.cat/wsceop/6748/Microdades%20anonimitzades%20cine-901.sav 

*Conversió
usespss Microdades%20anonimitzades%20cine-901.sav
save "ceo18_2.dta", replace

*Obrim les dades

use "ceo18_2.dta", clear

*Neteja casos perduts

foreach var of varlist P56A-P56J {
gen `var'_r=`var'
recode `var'_r 98=.a 99=.b
}

*Recodificar en 3 categories

label define acord 1"Molt/Bastant d'acord" 2"Ni d'acord ni en desacord" 3"Bastant/Molt en desacord"

foreach var of varlist P56A-P56J {
gen `var'_3=`var'
recode `var'_3 98=.a 99=.b 1/2=1 3=2 4/5=3
label values   `var'_3 acord
}

*Genera taula 1
tabout P56A_3 P56B_3 P56C_3 P56D_3 P56E_3 P56F_3 P56G_3 P56H_3 P56I_3 P56J_3 [aw=POND] using taula.xls, replace oneway cells(col) format(2c) layout(col)

*Girem el sentit de les preguntes

foreach var of varlist P56H P56F P56D P56C {
replace `var'_r=(`var'_r*-1)+6
}

*Exploració pre-factorial
tab1 P56*_r

pwcorr P56*_r

rename P56A_r interveco
rename P56B_r impostos
rename P56C_r desigual
rename P56D_r lgtb
rename P56E_r escola
rename P56F_r religio
rename P56G_r llei
rename P56H_r eutanasia
rename P56I_r immigr
rename P56J_r ecomediamb

*Dimensionalitat

factor interveco-ecomediamb, mineigen(1) pcf
rotate, oblimin oblique
scoreplot

*Guardem els tres factors
predict f1 f2 f3
label var f1 autoritarisme
label var f2 religio
label var f3 socioecon
pwcorr f1 f2 f3

*Reescalem de 0 a 10

foreach var in f1 f2 f3 {
		qui sum `var'
		replace `var' = (`var' - `r(min)') / (`r(max)'-`r(min)')
		replace `var'=`var'*-1+1
		replace `var'=`var'*10
		sum `var'
	}

*Densitats
twoway (kdensity f1) (kdensity f2) (kdensity f3) 

*Relació amb ideologia
recode P25 98/99=., gen(ideol)
reg f1 ideol
margins, at(ideol=(0(1)10)) post
est store Autoritarisme

reg f2 ideol
margins, at(ideol=(0(1)10)) post
est store Religió


reg f3 ideol
margins, at(ideol=(0(1)10)) post
est store Socioeconòmica

coefplot Autoritarisme Religió Socioeconòmica, at xtitle("Autoubicació Esquerra-dreta") ytitle("Dimensions ideològiques") title("Ideologia declarada i estimada") noci lwidth(*1) connect(l) xline(5)

pwcorr f1 f2 f3 ideol

*Relació amb l'independentisme	
recode P25 98/99=., gen(ideol)
replace ideol=ideol/10

recode P31 (98=.a) (99=.b), gen(indep)
tabstat f1 f2 f3, by(indep)
ttest  f1, by(indep)
ttest  f2, by(indep)
ttest  f3, by(indep)
ttest  ideol, by(indep)

cibplot f1, by(indep) name(f1)
cibplot f2, by(indep) name(f2)
cibplot f3, by(indep) name (f3)
cibplot ideol, by(indep) name(ideol)
graph combine f1 f2 f3 ideol

twoway (kdensity f1 if indep==1) (kdensity f1 if indep==2),  name(f1dens)
twoway (kdensity f2 if indep==1) (kdensity f2 if indep==2),  name(f2dens)
twoway (kdensity f3 if indep==1) (kdensity f3 if indep==2),  name(f3dens)
twoway (kdensity ideol if indep==1, bw(1)) (kdensity ideol if indep==2, bw(1)), name(ideoldens)
graph combine f1dens f2dens f3dens ideoldens

*Relació amb partits

recode P24R (6=2 "Cs") (1=1 "PP") (21=3 "JxC") (3=5 "ERC") (4=4 "PSC") (22=6 "CeC") (10=7 "CUP") (80/99=.), gen(simpatia)
tabstat f1 f2 f3 ideol, by(simpatia)
cibplot f2 if P38_CENSR<80, by(P24R)